PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: justforlxz <justforlxz@gmail.com>

pkgname=dde-shell-git
_pkgname=dde-shell
pkgver=0.0.4.r2.g1bf0b28
pkgrel=1
pkgdesc='New DDE shell'
arch=('x86_64' 'aarch64')
url="https://github.com/linuxdeepin/dde-shell"
license=('LGPL3')
depends=('dtk6declarative-git' 'qt6-wayland')
makedepends=('git' 'qt6-tools' 'qt5-tools' 'dtk6declarative-git' 'qt6-wayland' 'cmake' 'ninja')
conflicts=('dde-shell')
provides=('dde-shell')
groups=('deepin-git')
source=("git+https://github.com/linuxdeepin/dde-shell.git")
sha512sums=('SKIP')

pkgver() {
    cd $srcdir/$_pkgname
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd $srcdir/$_pkgname
  cmake -B build -GNinja \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  cmake --build build
}

package() {
  cd $srcdir/$_pkgname/build
  DESTDIR="$pkgdir" ninja install
}