PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
#
# Upstream: https://git.metalpunks.info/arch-ports

_pkgname=deadbeef-lyricbar
pkgname=deadbeef-plugin-lyricbar-git
pkgver=r202.g3383709
pkgrel=1
pkgdesc="DeaDBeeF lyric bar plugin"
arch=('x86_64' 'i686')
url="https://github.com/AsVHEn/deadbeef-lyricbar"
license=('MIT')
provides=('deadbeef-plugin-lyricbar')
conflicts=('deadbeef-plugin-lyricbar')
depends=('deadbeef'
         'glibc'
         'libgcc'
         'libstdc++'
         'libsigc++'
         'glib2'
         'glibmm'
         'gtk3'
         'gtkmm3'
         'pangomm'
         'curl')
makedepends=('git' 'pkgconf' 'taglib')
source=("${_pkgname}::git+${url}"
        "${_pkgname}-makefile.patch")
sha256sums=('SKIP'
            '226daee6935c5826d0ad1cefc5671b1c667352017605c852a962b49a727f84c8')

pkgver() {
  cd "${_pkgname}"
  printf "r%s.g%s" \
    "$(git rev-list --count HEAD)" \
    "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "${_pkgname}"

  # Arch compile FLAGS
  patch -p1 -i ../${_pkgname}-makefile.patch

  # Fucked up Makefile
  glib-compile-resources --generate-source src/resources.xml
  glib-compile-resources --generate-header src/resources.xml
}

build() {
  cd "${_pkgname}"
  make COPTS="${CFLAGS}" CXXOPTS="${CXXFLAGS}"
}

package() {
  cd "${_pkgname}"
  make prefix="${pkgdir}/usr" install
  install -Dvm0644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}