blob: 1fc2dce1b5ec0fcf864b3b0d65c3de7c23d6ead1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Andy Alt <arch_stanton5995 at proton.me>
pkgname=dealers-choice
pkgver=0.0.15
pkgrel=1
pkgdesc="Online Multiplayer Stud and Draw Poker, Texas Hold'em and Omaha"
arch=('x86_64')
url="https://github.com/Dealer-s-Choice/dealers-choice"
license=('MIT')
depends=(
'canfigger'
'glibc'
'hicolor-icon-theme'
'libsodium'
'pcg-c'
'protobuf-c'
'sdl2'
'sdl2_image'
'sdl2_ttf'
)
makedepends=(
'meson'
'ninja'
)
source=("https://github.com/Dealer-s-Choice/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz")
sha256sums=('c8c7030d281c0e8f14faf7473478f366ad2f22391f05f9f7deaa33066df39b89')
build() {
arch-meson "${pkgname}-${pkgver}" build
meson compile -C build
}
check() {
# Deterministic suites + fast unit tests only. The networked game_logic
# tests and the tcpme loopback tests are skipped on purpose: they are
# timing-sensitive and flaky inside build sandboxes.
meson test -C build --no-rebuild --print-errorlogs --suite deckhandler --suite pokeval
meson test -C build --no-rebuild --print-errorlogs \
test_serialization test_get_next_player test_debug_print_cards \
test_layout_cards test_no_peek test_rate_limit test_sodium_compat
}
package() {
DESTDIR="${pkgdir}" meson install -C build
install -Dm 644 "${pkgname}-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
}
|