blob: 9c5fc8d5b366ed9c516a407ecd025914122864ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Maintainer:
# Contributor: Justin Vreeland <vreeland.justin@gmail.com>
# Contributor: Antoine Lubineau <antoine@lubignon.info>
# Contributor: Charles Pigott <charlespigott@googlemail.com>
# Contributor: Andrei "Garoth" Thorp <garoth "at the nice" gmail "dot" com>
## options
: ${_build_git:=false}
unset _pkgtype
[[ "${_build_git::1}" == "t" ]] && _pkgtype+="-git"
## basic info
_pkgname="debhelper"
pkgname="$_pkgname${_pkgtype:-}"
pkgver=13.13
pkgrel=1
pkgdesc="A collection of programs that can be used in a debian/rules file to automate common tasks"
url="https://salsa.debian.org/debian/debhelper"
license=('GPL-2.0-or-later')
arch=('any')
_url_dh_strip_nondeterminism="https://salsa.debian.org/reproducible-builds/strip-nondeterminism"
depends=(
'dpkg'
'perl-pod-parser'
)
makedepends=(
'git'
'po4a'
)
optdepends=(
'dh-make: convert source archives into Debian package source'
)
if [ "${_build_git::1}" != "t" ] ; then
# stable package
_pkgsrc="$_pkgname"
source=("git+$url.git#tag=debian/${pkgver%%.r*}")
sha256sums=('SKIP')
pkgver() {
echo "${pkgver%%.r*}"
}
else
# git package
provides=("$_pkgname")
conflicts=("$_pkgname")
_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd "$_pkgsrc"
git describe --long --tags | sed 's/^debian\///;s/\([^-]*-g\)/r\1/;s/-/./g'
}
fi
provides+=("dh-strip-nondeterminism")
conflicts+=("dh-strip-nondeterminism")
source+=("dh_strip_nondeterminism"::"$_url_dh_strip_nondeterminism/-/raw/master/bin/dh_strip_nondeterminism")
sha256sums+=('SKIP')
prepare() {
cd "$_pkgsrc"
# prevent unicode error
rm "man/po4a/po"/*.po
}
build() {
cd "$_pkgsrc"
make
}
package() {
depends+=(
'binutils'
'file'
'man-db'
'python-html2text'
'strip-nondeterminism'
# AUR
'po-debconf'
)
cd "$_pkgsrc"
make DESTDIR="$pkgdir" install
install -Dm755 "$srcdir/dh_strip_nondeterminism" -t "$pkgdir/usr/bin"
}
# vim:set ts=2 sw=2 et:
|