PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Build and install DebOps on the Arch Linux host
#
# Copyright (C) 2017 Maciej Delmanowski <drybjed@gmail.com>
# Copyright (C) 2017 DebOps project https://debops.org/

# To install DebOps on Arch Linux, after cloning the repository, run:
#
#     makepkg -si
#
# This will install all of the required dependencies, then build and install
# the DebOps Python package.
#
# After installation, run 'debops-update' to download or update the
# role/playbook code from GitHub. The DebOps monorepo will be downloaded in
# '~/.local/share/debops/debops/' directory on your user account.


# Maintainer: Maciej Delmanowski <drybjed@gmail.com>
pkgname=debops-git
_pkgname=debops
pkgver=0.8.0
pkgrel=1
pkgdesc="Your Debian-based data center in a box"
arch=('any')
url="https://github.com/debops/debops/"
license=('GPL3')
depends=('python' 'ansible' 'python-dnspython' 'python-netaddr' 'python-ldap' 'python-passlib' 'python-future' 'util-linux' 'encfs' 'gnupg')
makedepends=('python-setuptools' 'git')
provides=('debops')
conflicts=('debops')
source=("$_pkgname::git+https://github.com/debops/debops")
sha256sums=('SKIP')

pkgver() {
    cd "$_pkgname"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g' | sed 's/v//'
}

build() {
    cd "$_pkgname"
    python setup.py build
}

package() {
    cd "$_pkgname"
    python setup.py install --root="$pkgdir" --optimize=1
}