summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 0aff1e9f88671c76582349c26fcab2b62e13b5ff (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
# Maintainer: Eduard Wirch <wirch.eduard@gmail.com>
# Contributor: Louis des Landes <aur@psykar.com>

pkgname=deepgit
pkgver=3.2
pkgrel=2
pkgdesc="A tool to investigate the history of source code."
arch=('any')
url="http://www.syntevo.com/deepgit/"
license=('custom')
depends=(
    'java-environment>=8'
    'hicolor-icon-theme'
    'desktop-file-utils'
)

source=(
    "https://www.syntevo.com/downloads/$pkgname/$pkgname-linux-${pkgver//./_}.tar.gz"
    "deepgit.sh"
    "deepgit.desktop"
)
sha1sums=(
    11f4dc96ab826ad6b1633ce7472a375f7f45153a
    23a92ccca3e7e452538cc7a9739c86a71dea474c
    8ab2e36b3cb2e6f7b5af70a4ddbe2e9d307d3988
)


package() {
    cd $srcdir
    # Copy ./lib to /usr/share/java/$pkgname/
    install -m 644 -Dt "$pkgdir/usr/share/java/$pkgname/lib/" $srcdir/$pkgname/lib/*

    # Add executable to /usr/bin
    install -T -Dm 755 deepgit.sh $pkgdir/usr/bin/deepgit

    # Copy license
    # /usr/share/licenses/$pkgname/LICENSE
    install -Dt "$pkgdir/usr/share/licenses/$pkgname/" $srcdir/$pkgname/licenses/*
    install -Dt "$pkgdir/usr/share/licenses/$pkgname/" "$srcdir/$pkgname/license.html" 

    # Desktop file
    install -Dm 644 -t $pkgdir/usr/share/applications/ deepgit.desktop 

    # Copy other stuff to /usr/share/$pkgname/
    cd $srcdir/$pkgname
    install -m 644 -Dt "$pkgdir/usr/share/$pkgname" changelog.txt known-issues.txt readme-linux.txt

    # Install some icons
    cd $srcdir/$pkgname/bin
    for size in 32 48 64 128
    do
        install -Dm 644 -T deepgit-$size.png $pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/deepgit.png
    done

}