PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: DingYuan Zhang <justforlxz@gmail.com>

pkgname=deepin-polkit-agent-git
pkgver=5.2.0.7.r1.g9d192f2
pkgrel=1
pkgdesc='Deepin Polkit Agent'
arch=('x86_64')
url="https://github.com/linuxdeepin/dde-polkit-agent"
license=('GPL3')
depends=('deepin-qt-dbus-factory-git' 'startdde-git' 'polkit-qt5' 'dtkwidget-git')
makedepends=('git' 'qt5-tools' 'dtkwidget-git')
conflicts=('deepin-polkit-agent')
replaces=('deepin-polkit-agent')
provides=('deepin-polkit-agent')
groups=('deepin-git')
source=('git://github.com/linuxdeepin/dde-polkit-agent')
sha512sums=('SKIP')

pkgver() {
    cd dde-polkit-agent
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd dde-polkit-agent
  # https://github.com/linuxdeepin/developer-center/issues/1721
  sed -i 's/bool is_deepin = true/bool is_deepin = false/' policykitlistener.cpp
}

build() {
  cd dde-polkit-agent
  qmake-qt5 PREFIX=/usr
  make
}

package() {
  cd dde-polkit-agent
  make INSTALL_ROOT="$pkgdir" install
}