blob: 07838e9a3bc0f32db54edf132490581857687e3f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Morten Linderud <morten@linderud.pw>
pkgname=dep-git
_pkgname=dep
pkgver=r2264.b0e3b27d
pkgrel=1
pkgdesc="Go dependency tool"
arch=('x86_64' 'i686')
url="https://github.com/golang/dep"
license=('BSD')
makedepends=('go' 'git')
options=('!strip' '!emptydirs')
source=("git://github.com/golang/dep.git")
sha256sums=('SKIP')
_gourl='github.com/golang/dep'
pkgver() {
cd "${_pkgname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
rm -rf "${srcdir}/src"
mkdir -p "$srcdir"/src/github.com/golang
ln -sf "$srcdir/$_pkgname" "$srcdir"/src/github.com/golang/dep
}
build() {
export GOPATH="$srcdir"
export GOBIN="$srcdir/bin"
export PATH=$PATH:$GOPATH/bin
cd "$GOPATH"/src/github.com/golang/dep/cmd/dep
go get .
}
package() {
cd "${_pkgname}"
install -Dm755 "../bin/${_pkgname}" "$pkgdir/usr/bin/${_pkgname}"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${_pkgname}/LICENSE"
}
# vim:set ts=2 sw=2 et:
|