PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

# Maintainer: yv-was-taken <yvmail@proton.me>
pkgname=desktop-waifu
pkgver=0.2.5
pkgrel=1
pkgdesc="Animated 3D VRM characters with AI-powered conversational chat - Wayland overlay"
arch=('x86_64')
url="https://github.com/yv-was-taken/desktop-waifu"
license=('MIT')
depends=(
    'gtk4'
    'webkit2gtk-4.1'
    'cairo'
    'glib2'
    'pango'
    'wayland'
    'dbus'
)
makedepends=(
    'cargo'
    'bun'
    'git'
    'nodejs'
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('SKIP')

prepare() {
    cd "$pkgname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')" --manifest-path desktop-waifu-overlay/Cargo.toml
}

build() {
    cd "$pkgname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target

    # Build frontend
    bun install --frozen-lockfile
    bun run build:web

    # Build Rust binary
    cargo build --release --locked --manifest-path desktop-waifu-overlay/Cargo.toml
}

package() {
    cd "$pkgname-$pkgver"

    # Install binary
    install -Dm755 "target/release/desktop-waifu-overlay" "$pkgdir/usr/bin/desktop-waifu"

    # Install frontend assets
    install -dm755 "$pkgdir/usr/share/desktop-waifu/dist"
    cp -r dist/* "$pkgdir/usr/share/desktop-waifu/dist/"

    # Install desktop entry
    install -Dm644 "packaging/desktop-waifu.desktop" "$pkgdir/usr/share/applications/desktop-waifu.desktop"

    # Install scripts
    install -Dm755 "scripts/setup-hotkey.sh" "$pkgdir/usr/share/desktop-waifu/scripts/setup-hotkey.sh"

    # Install license
    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}