blob: 54000f478f7c35f65cd82d5a491a4fe58f5db87f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: David Runge <dvzrv@archlinux.org>
pkgname=deteriorate-lv2
pkgver=1.0.7
pkgrel=3
pkgdesc="A set of plugins to deteriorate the sound quality of a live input"
arch=('x86_64')
url="https://github.com/blablack/deteriorate-lv2"
license=('GPL3')
groups=('lv2-plugins' 'pro-audio')
depends=('fontconfig' 'gcc-libs' 'glibc' 'gtkmm')
makedepends=('atkmm' 'cairomm' 'freetype2' 'glib2' 'glibmm' 'libsigc++' 'lv2'
'lvtk' 'pango' 'waf')
checkdepends=('lv2lint')
source=("$pkgname-$pkgver.tar.gz::https://github.com/blablack/${pkgname}/archive/v${pkgver}.tar.gz")
sha512sums=('dec154c7f45cb69906245993e03d5551ff06a052d50fae753d52643a1cf9ed60479c76d586bd0e9b7606cd4e5b3b866e80a791b9c21dd6cdd7415f9687ff847e')
b2sums=('6ee4f790f143bb3756acdcbecab5f339fa53afbb1443a811c35c8ca74cd71b1bef6d43be5ef67d15d694f1a76b01c714b40e64e945f2443f769ee15abb4db8ad')
prepare() {
cd "${pkgname}-${pkgver}"
# let wscript(s) find the custom waf scripts
mkdir -pv tools
touch __init__.py
cp -v waflib/extras/{autowaf,lv2}.py tools/
mkdir -pv plugins/tools/
cp -v waflib/extras/{autowaf,lv2}.py plugins/tools/
rm -rv waflib
sed -e 's/waflib.extras/tools/g' \
-e "s/load('autowaf'/load('autowaf', tooldir='tools'/g" \
-e "s/load('lv2'/load('lv2', tooldir='tools'/g" \
-i wscript
}
build() {
cd "$pkgname-$pkgver"
export LINKFLAGS="$LDFLAGS"
waf configure --prefix=/usr
waf
}
check() {
local _name
cd "$pkgname-$pkgver"
for _name in {downsampler_{mono,stereo},granulator_{mono,stereo}}; do
lv2lint -Mpack \
-I "build/${pkgname//-/.}" \
"https://github.com/blablack/deteriorate-lv2/${_name}" \
|| echo "Known to fail: https://github.com/blablack/deteriorate-lv2/issues/10"
done
}
package() {
depends+=('libatkmm-1.6.so' 'libcairomm-1.0.so' 'libglibmm-2.4.so' 'libsigc-2.0.so')
cd "$pkgname-$pkgver"
waf install --destdir="$pkgdir/"
install -vDm 644 {THANKS,README.md} -t "${pkgdir}/usr/share/doc/${pkgname}"
}
|