blob: fe0e610cc90a75aa48a5f92843540440bd08c2a6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Florian Bruhin (The Compiler) <archlinux.org@the-compiler.org>
pkgname=devpi-server
pkgver=6.4.0
pkgrel=1
pkgdesc="Python PyPi staging server and release tool"
arch=('any')
url="https://doc.devpi.net/"
license=('MIT')
groups=('devpi')
depends=(
'python>=3.7'
'python-py'
'python-argon2_cffi'
'python-appdirs'
'python-attrs'
'python-defusedxml'
'devpi-common'
'python-execnet'
'python-itsdangerous'
'python-passlib'
'python-pluggy'
'python-pyramid'
'python-repoze.lru'
'python-ruamel-yaml'
'python-waitress'
'python-strictyaml')
makedepends=('python-setuptools' 'python-build' 'python-install' 'python-wheel')
optdepends=('devpi-client')
changelog=CHANGELOG
source=(
"$pkgname-$pkgver.tar.gz::https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$pkgname-$pkgver.tar.gz"
'devpi-server.service'
'devpi-server.sysusers'
'devpi-server.tmpfiles')
sha256sums=('ff2d973a3d2caa8ad0938e68162c482ef128ab02efa4c2d7c9b7425c37f8eb23'
'1ebfe9edc2bf0f368162f15540e48a8e046db0023b5da23e98daf43f0e075a95'
'4327d0e72b277ef7b05dfb4b3bac6ab4c70d55a96c9ad114a90ebb00c954bd48'
'bcd2321ff41bebcf08392ca02dbfaa0ac2693eba3432f0e5793ff384753ce0f1')
build() {
cd "$pkgname-$pkgver"
python -m build --wheel --skip-dependency-check --no-isolation
}
package() {
install -Dm644 "$pkgname.service" -t "$pkgdir/usr/lib/systemd/system/"
install -Dm644 "$pkgname.sysusers" "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
install -Dm644 "$pkgname.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
export PYTHONHASHSEED=0
cd "$pkgname-$pkgver"
python -m install --optimize=1 --destdir="$pkgdir/" dist/*.whl
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm644 README.rst AUTHORS -t "$pkgdir/usr/share/doc/$pkgname/"
}
# vim:set ts=2 sw=2 et:
|