blob: 42779c85fc36107781d792a0278270f4631f7900 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Christian Krause ("wookietreiber") <christian.krause@mailbox.org>
# shellcheck disable=2034
# shellcheck disable=2148
pkgname=dfhack-bin
_pkgname=dfhack
pkgver=0.44.08
_pkgver=$pkgver-alpha1
pkgrel=1
pkgdesc="memory hacking library for Dwarf Fortress and a set of tools that use it"
arch=('x86_64' 'i686')
url="https://dfhack.readthedocs.io/en/stable/"
license=('custom')
depends=("dwarffortress=$pkgver" lua protobuf libpng12 libxrandr libjpeg6 freetype2 libglvnd libxcursor libxinerama)
conflicts=(dfhack dfhack-git)
provides=(dfhack)
source_i686=("https://github.com/DFHack/dfhack/releases/download/$_pkgver/dfhack-$_pkgver-Linux-32-gcc-7.tar.bz2")
source_x86_64=("https://github.com/DFHack/dfhack/releases/download/$_pkgver/dfhack-$_pkgver-Linux-64-gcc-7.tar.bz2")
source=(dfhack.sh
dfhack-run.sh)
md5sums=('81f5909c1a32391679f968e40f24d5ca'
'3853c6f890d3541f710f2c4833a9e696')
md5sums_x86_64=('c94f46739a762547f2a12e42048442c7')
md5sums_i686=('f7ee4d034e9f02c463fe13f5e0b1364e')
prepare() {
# shellcheck disable=2154
sed -e 's|setarch i386 -R ||' \
-i "$srcdir"/dfhack
}
package() {
# shellcheck disable=2154
install -d "$pkgdir"/opt/dwarffortress
cp -r "$srcdir"/{hack,dfhack,dfhack-run,dfhack-config,dfhack.init-example,stonesense} "$pkgdir"/opt/dwarffortress
install -Dm755 "$srcdir"/dfhack.sh "$pkgdir"/usr/bin/dfhack
install -Dm755 "$srcdir"/dfhack-run.sh "$pkgdir"/usr/bin/dfhack-run
install -Dm644 "$srcdir"/hack/LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|