blob: c685a5755703067f995f166597a33d55821228f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Christian Krause ("wookietreiber") <christian.krause@mailbox.org>
# Co-Maintainer: Ziusudra <ziusudra.zoon@gmail.com>
# shellcheck disable=2034
# shellcheck disable=2148
pkgname=dfhack-bin
_pkgname=dfhack
pkgver=0.47.05
_pkgver=$pkgver-r5
pkgrel=6
pkgdesc="memory hacking library for Dwarf Fortress and a set of tools that use it"
arch=('x86_64' 'i686')
url="https://dfhack.readthedocs.io/en/stable/"
license=('custom')
depends=("dwarffortress=$pkgver" lua protobuf libpng12 libxrandr libjpeg6 freetype2 libglvnd libxcursor libxinerama libxcrypt-compat)
conflicts=(dfhack dfhack-git)
provides=(dfhack)
source_i686=("https://github.com/DFHack/dfhack/releases/download/$_pkgver/dfhack-$_pkgver-Linux-32bit-gcc-7.tar.bz2")
source_x86_64=("https://github.com/DFHack/dfhack/releases/download/$_pkgver/dfhack-$_pkgver-Linux-64bit-gcc-7.tar.bz2")
source=(dfhack.sh
dfhack-run.sh)
md5sums_i686=('855623ae47ff386223764c6fdd5d43d1')
md5sums_x86_64=('37d56b99b1c11c1a76bdd635ba8ebf64')
md5sums=('81f5909c1a32391679f968e40f24d5ca'
'3853c6f890d3541f710f2c4833a9e696')
prepare() {
# shellcheck disable=2154
sed -e 's|setarch i386 -R ||' \
-i "$srcdir"/dfhack
}
package() {
# shellcheck disable=2154
install -d "$pkgdir"/opt/dwarffortress
cp -r "$srcdir"/{hack,dfhack,dfhack-run,dfhack-config,dfhack.init-example,stonesense} "$pkgdir"/opt/dwarffortress
install -Dm755 "$srcdir"/dfhack.sh "$pkgdir"/usr/bin/dfhack
install -Dm755 "$srcdir"/dfhack-run.sh "$pkgdir"/usr/bin/dfhack-run
install -Dm644 "$srcdir"/hack/LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|