blob: a4f66236340183476990199e5102c79cf4c8e365 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Dan Johansen <strit@strits.dk>
_pkgname=settings
pkgbase=dfl-settings
pkgname=('dfl-settings' 'dfl-settings-qt6')
pkgver=0.2.0
pkgrel=1
pkgdesc="A class that extends QSettings"
arch=('x86_64' 'aarch64')
url="https://gitlab.com/desktop-frameworks/$_pkgname"
license=('GPL3')
makedepends=('meson' 'ninja' 'qt5-base' 'qt6-base')
source=("$url/-/archive/v${pkgver}/${_pkgname}-v${pkgver}.tar.gz")
md5sums=('06806618ad42243ceed7297fc3963533')
build() {
cd "${_pkgname}-v${pkgver}"
echo "Building QT5 version..."
meson .build --prefix=/usr --buildtype=release
ninja -C .build
echo "Building QT6 version..."
meson .build-qt6 --prefix=/usr -Duse_qt_version=qt6 --buildtype=release
ninja -C .build-qt6
}
package_dfl-settings() {
depends=('qt5-base')
cd "${_pkgname}-v${pkgver}"
DESTDIR="${pkgdir}" ninja -C .build install
}
package_dfl-settings-qt6() {
depends=('qt6-base')
cd "${_pkgname}-v${pkgver}"
DESTDIR="${pkgdir}" ninja -C .build-qt6 install
}
|