blob: 292226d9d73adc856afec20039371ffabac1b3eb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=dhcpcd-git
pkgver=7.1.1.r31.gf1713f60
pkgrel=1
pkgdesc="A DHCP and DHCPv6 client"
arch=('i686' 'x86_64')
url="https://roy.marples.name/projects/dhcpcd"
license=('BSD')
depends=('glibc' 'sh' 'systemd-libs')
makedepends=('git')
optdepends=('openresolv: resolvconf support')
provides=('dhcpcd' 'dhcp-client')
conflicts=('dhcpcd')
backup=('etc/dhcpcd.conf')
options=('emptydirs')
source=("git+https://roy.marples.name/git/dhcpcd.git"
"dhcpcd.service::https://git.archlinux.org/svntogit/packages.git/plain/trunk/dhcpcd.service?h=packages/dhcpcd"
"dhcpcd_.service::https://git.archlinux.org/svntogit/packages.git/plain/trunk/dhcpcd_.service?h=packages/dhcpcd")
sha256sums=('SKIP'
'SKIP'
'SKIP')
pkgver() {
cd "dhcpcd"
git describe --long --tags | sed 's/^dhcpcd-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "dhcpcd"
./configure \
--prefix="/usr" \
--sysconfdir="/etc" \
--sbindir="/usr/bin" \
--libexecdir="/usr/lib/dhcpcd" \
--dbdir="/var/lib/dhcpcd" \
--rundir="/run"
make
}
check() {
cd "dhcpcd"
make test
}
package() {
cd "dhcpcd"
make DESTDIR="$pkgdir" install
install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/dhcpcd/LICENSE"
# Disable ip4vall
echo "noipv4ll" >> "$pkgdir/etc/dhcpcd.conf"
install -Dm644 "$srcdir/dhcpcd.service" "$pkgdir/usr/lib/systemd/system/dhcpcd.service"
install -Dm644 "$srcdir/dhcpcd_.service" "$pkgdir/usr/lib/systemd/system/dhcpcd@.service"
}
|