blob: 2eeaa9823a1033d078e5466f7801397ac4ad9456 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=dhcpcd8
pkgver=8.1.9
pkgrel=2
pkgdesc="A DHCP and DHCPv6 client (8.x releases)"
arch=('i686' 'x86_64')
url="https://roy.marples.name/projects/dhcpcd/"
license=('BSD')
depends=('glibc' 'sh' 'systemd-libs')
optdepends=('openresolv: resolvconf support')
provides=("dhcpcd=$pkgver")
conflicts=('dhcpcd')
backup=('etc/dhcpcd.conf')
options=('emptydirs')
source=("$pkgname-$pkgver-src.tar.gz::https://github.com/NetworkConfiguration/dhcpcd/archive/refs/tags/dhcpcd-$pkgver.tar.gz"
"dhcpcd.service::https://raw.githubusercontent.com/archlinux/svntogit-packages/packages/dhcpcd/trunk/dhcpcd.service"
"dhcpcd_.service::https://raw.githubusercontent.com/archlinux/svntogit-packages/packages/dhcpcd/trunk/dhcpcd_.service")
sha256sums=('951ec48cb5a5113cccfcdc713e909023df08f17adca3f74c52afc1d16c519398'
'20bccbf8a05b1bc2be365c8b4b526c38c752f48229ba53c3be113ac5b634f210'
'37acd53a589711f5e1db2fcaebb4ccf1c90dc4bcd309626bde25beb7b630a545')
build() {
cd "dhcpcd-dhcpcd-$pkgver"
./configure \
--prefix="/usr" \
--sysconfdir="/etc" \
--sbindir="/usr/bin" \
--libexecdir="/usr/lib/dhcpcd" \
--dbdir="/var/lib/dhcpcd" \
--rundir="/run"
make
}
check() {
cd "dhcpcd-dhcpcd-$pkgver"
make test
}
package() {
cd "dhcpcd-dhcpcd-$pkgver"
make DESTDIR="$pkgdir" install
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/dhcpcd"
# Disable ip4vall
echo "noipv4ll" >> "$pkgdir/etc/dhcpcd.conf"
install -Dm644 "$srcdir/dhcpcd.service" -t "$pkgdir/usr/lib/systemd/system"
install -Dm644 "$srcdir/dhcpcd_.service" "$pkgdir/usr/lib/systemd/system/dhcpcd@.service"
}
|