blob: 6c18df169d819ebd495a701ee9b608c04c745e74 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: Mufeed Ali <lastweakness@tuta.io>
pkgname=dialect
pkgver=1.4.1
pkgrel=1
pkgdesc="A translation app for GNOME."
arch=('any')
url="https://apps.gnome.org/app/com.github.gi_lom.dialect"
license=('GPL3')
depends=('gst-python' 'gtk3' 'libhandy' 'python-gobject' 'python-googletrans'
'python-gtts' 'python-httpx' )
makedepends=('git' 'gobject-introspection' 'meson')
checkdepends=('appstream-glib')
conflicts=('gnabel')
replaces=('gnabel')
source=("git+https://github.com/dialect-app/dialect.git#tag=$pkgver"
'git+https://github.com/dialect-app/po.git')
sha256sums=('SKIP'
'SKIP')
prepare() {
cd "$srcdir/$pkgname"
git submodule init
git config submodule.po.url $srcdir/po
git submodule update
}
build() {
arch-meson "$pkgname" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "$pkgdir"
}
|