blob: e33aa7ef559f3b44f648d987a07a6c44ce9216ca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Mufeed Ali <lastweakness@tuta.io>
pkgname=dialect
pkgver=2.2.0
pkgrel=1
pkgdesc="A translation app for GNOME."
arch=('any')
url="https://apps.gnome.org/Dialect"
license=('GPL-3.0-or-later')
depends=('dbus-python' 'gst-python' 'libadwaita' 'libsoup3' 'python-gobject' 'python-gtts')
makedepends=('blueprint-compiler' 'git' 'gobject-introspection' 'meson')
checkdepends=('appstream-glib')
_commit=93ad6c170363ff2c3d27c7f72eb5c67ffff85188 # tags/2.2.0^0
source=("git+https://github.com/dialect-app/dialect.git#commit=$_commit"
'git+https://github.com/dialect-app/po.git')
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd "$pkgname"
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd "$pkgname"
git submodule init
git config submodule.po.url "$srcdir/po"
git -c protocol.file.allow=always submodule update
}
build() {
arch-meson "$pkgname" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "$pkgdir"
}
|