blob: ef36c431ff35663976c4e8f29061ec4eac10555a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Bipin Kumar <kbipinkumar@pm.me>
# shellcheck disable=2034
# shellcheck disable=2148
pkgname=diamond
pkgver=2.1.16
pkgrel=1
pkgdesc="High performance sequence aligner for protein and translated DNA searches with big sequence data. https://doi.org/10.1038/s41592-021-01101-x"
arch=('x86_64')
url="https://github.com/bbuchfink/diamond"
license=('GPL-3.0-only')
depends=('gcc-libs' 'zlib' 'zstd' 'glibc' 'blast+' 'lmdb')
makedepends=('cmake' 'mold')
source=("$pkgname-$pkgver.tar.gz::https://github.com/bbuchfink/diamond/archive/v$pkgver.tar.gz")
sha256sums=('bdbe7264ea64c29745af83a011345f6fa4b9a5c98e89fbaaba3f04e088f821a8')
prepare() {
cd $pkgname-$pkgver
# enable build with newer version of cmake.
sed -i 's/cmake_minimum_required (VERSION 2.6)/cmake_minimum_required (VERSION 3.5)/g' CMakeLists.txt
# set correct documentation link.
sed -i 's|http://www.diamondsearch.org|https://github.com/bbuchfink/diamond/|g' src/basic/config.cpp
sed -i 's|http://www.diamondsearch.org|https://github.com/bbuchfink/diamond/wiki/3.-Command-line-options|g' src/util/command_line_parser.cpp
}
build() {
cd $pkgname-$pkgver
cmake -B build \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_SHARED_LINKER_FLAGS="-fuse-ld=mold" \
-DCMAKE_EXE_LINKER_FLAGS="-Wl,-z,relro -Wl,-z,now,-fuse-ld=mold" \
-DWITH_ZSTD=ON \
-DBLAST_INCLUDE_DIR=/usr/include/ncbi-tools++ \
-DBLAST_LIBRARY_DIR=/usr/lib/blast+ \
-DZSTD_LIBRARY=/usr/lib/libzstd.so \
-DZLIB_INCLUDE_DIR=/usr/include \
-W no-dev
cmake --build build
}
check() {
cd $pkgname-$pkgver
ctest --test-dir build --output-on-failure
}
package() {
cd $pkgname-$pkgver
DESTDIR="$pkgdir" cmake --install build
}
|