PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Einhard Leichtfuß <archer@respiranto.de>
_lang=fra-eng
_pkgname=dict-freedict-${_lang}
pkgname=${_pkgname}-svn
pkgver=r1487
pkgrel=1
pkgdesc="French -> English dictionary for dictd et al. from Freedict.org"
arch=('any')
url="http://www.freedict.org/"
license=('GPL')
optdepends=('dictd: dict client and server')
makedepends=('subversion' 'dictd' 'freedict-tools')
provides=(${_pkgname})
conflicts=(${_pkgname})
install=${pkgname}.install
source=("svn+https://github.com/freedict/fd-dictionaries/trunk/${_lang}")
md5sums=('SKIP')

pkgver()
{
	cd ${_lang}
	local _ver="$(svnversion)"
	printf "r%s" "${_ver//[[:alpha:]]}"
}

prepare()
{
	ln -s /usr/lib/freedict-tools/{tools,shared} .
}

build()
{
	cd ${_lang}
	make
}

package()
{
	mkdir -p "${pkgdir}/usr/share/dictd"
	cp ${_lang}/${_lang}.{dict.dz,index} "$pkgdir/usr/share/dictd/"

	mkdir -p "${pkgdir}/usr/share/doc/freedict/${_lang}"
	for file in ${_lang}/{AUTHORS,README,NEWS,INSTALL,ChangeLog}
	do
		test -f ${file} && \
			cp -d ${file} "${pkgdir}/usr/share/doc/freedict/${_lang}/"
	done
}