blob: 99818a63b58a04117152136f84fcf6a2188e1875 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: Luis Martinez <luis dot martinez at disroot dot org>
pkgname=diffsitter
pkgver=0.8.3
pkgrel=1
pkgdesc="Tree-sitter based AST diff tool"
arch=(x86_64 i686 arm aarch64)
url="https://github.com/afnanenayet/${pkgname}"
license=(MIT)
depends=(tree-sitter)
makedepends=(git cargo)
checkdepends=(tree-sitter-cpp tree-sitter-python tree-sitter-rust)
options=('!lto')
source=(git+${url}.git?signed#tag=v${pkgver})
sha512sums=('bb8a927a7e50ea1c2729667f3bbf22f54060df6a7febed1d4e839ff910ba78ac0dad49ef0c1921075e7ca25b1258688f9c2632c1b1143b7f3f31f1e7df487fd4')
validpgpkeys=('1C519E4FEF5757BFB30C636494EEFE1FD178056B') # Afnan Enayet <afnan@afnan.io>
prepare() {
cd ${pkgname}
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cd ${pkgname}
cargo build --release --frozen --no-default-features --features dynamic-grammar-libs
}
check() {
export RUSTUP_TOOLCHAIN=stable
cd ${pkgname}
cargo test --frozen --no-default-features --features dynamic-grammar-libs
}
package() {
cd ${pkgname}
install -D "target/release/$pkgname" -t "$pkgdir/usr/bin/"
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
}
|