blob: 4747d721026cd4356d3b0e578a3fdb7b0641749b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: yogh-io <info@yogh.nl>
pkgname=diffstalker-git
pkgver=0.1.4.r0.g592e42c
pkgrel=1
pkgdesc="Terminal UI for git staging, committing, and reviewing changes"
arch=('any')
url="https://github.com/yogh-io/diffstalker"
license=('MIT')
depends=('nodejs')
makedepends=('npm' 'git')
provides=('diffstalker')
conflicts=('diffstalker')
source=("${pkgname}::git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --long --tags --abbrev=7 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "0.1.0.r%s.g%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
build() {
cd "$pkgname"
npm ci --ignore-scripts
npm run bundle
}
package() {
cd "$pkgname"
# Install bundled files to /usr/lib/diffstalker
install -dm755 "$pkgdir/usr/lib/diffstalker"
cp -r dist/bundle/* "$pkgdir/usr/lib/diffstalker/"
# Create wrapper script
install -dm755 "$pkgdir/usr/bin"
cat > "$pkgdir/usr/bin/diffstalker" << 'EOF'
#!/bin/sh
exec node /usr/lib/diffstalker/index.js "$@"
EOF
chmod 755 "$pkgdir/usr/bin/diffstalker"
# Install license and documentation
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
|