blob: 92569cf6551ed6bab1684d1fb6d3bde3c12be51d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Gunnar Bretthauer <taijian@posteo.de>
# Contributor: AudioLinux <audiolinux AT fastmail DOT fm>
# Contributor: Ronald van Haren <ronald@archlinux.org>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
_pkgname=digikam
pkgname=digikam-without-akonadi-mediawiki-vkontakte
_pkgver=7.10.0
pkgver=${_pkgver//-/_} # for beta versions
pkgrel=1
pkgdesc='An advanced digital photo management application'
arch=(x86_64)
license=(GPL)
url='https://www.digikam.org/'
depends=(lensfun opencv knotifyconfig libksane kfilemetadata qtav marble-common threadweaver kcalendarcore
qt5-xmlpatterns imagemagick jasper glu perl-image-exiftool)
makedepends=(extra-cmake-modules doxygen eigen boost kdoctools)
conflicts=('digikam' 'digikam-git')
provides=('digikam')
optdepends=('hugin: panorama tool' 'qt5-imageformats: support for additional image formats (WEBP, TIFF)'
'rawtherapee: RAW import' 'darktable: RAW import'
'perl: for digitaglinktree')
source=(https://download.kde.org/stable/$_pkgname/$pkgver/digiKam-$_pkgver.tar.xz{,.sig}
ffmpeg5.patch)
sha256sums=('a3f30f01b7d1b6d585822bcd5ebf8df69e0ff024563a72462ebf8069dbda22e1'
'SKIP'
'ef2601f9b2e668116a3643b4bd7ddcfc233ccfc747d813955423ca17b6a23dee')
validpgpkeys=(D1CF2444A7858C5F2FB095B74A77747BC2386E50) # digiKam.org (digiKam project) <digikamdeveloper@gmail.com>
prepare() {
patch -d $_pkgname-$_pkgver -p1 < ffmpeg5.patch # Fix build with FFmpeg 5
}
build() {
cmake -B build -S $_pkgname-$_pkgver \
-DBUILD_TESTING=OFF \
-DENABLE_KFILEMETADATASUPPORT=ON \
-DENABLE_MEDIAPLAYER=ON \
-DENABLE_AKONADICONTACTSUPPORT=OFF \
-DENABLE_MYSQLSUPPORT=ON \
-DENABLE_APPSTYLES=ON \
-DENABLE_QWEBENGINE=ON
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
}
|