blob: 686b1c174b8b87e08155065a3b500f3f38806e27 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Ilyas Turki <ilyasturki at gmail dot com>
pkgname=dircmp
pkgver=1.5.1
pkgrel=1
pkgdesc="Terminal TUI for comparing two directories side by side"
arch=('x86_64' 'aarch64')
url="https://github.com/ilyasturki/dircmp"
license=('MIT')
depends=('nodejs' 'dbus')
makedepends=('npm')
optdepends=('rclone: remote directory support')
conflicts=('dircmp-bin')
source=("https://registry.npmjs.org/@ilyasturki/${pkgname}/-/${pkgname}-${pkgver}.tgz")
noextract=("${pkgname}-${pkgver}.tgz")
sha256sums=('3a403031ea8474344a62e3bbaa5c2e7d7bb7a61e891200b7013f40a57b8377a2')
package() {
npm install -g \
--cache "${srcdir}/npm-cache" \
--prefix "${pkgdir}/usr" \
--omit=dev \
"${srcdir}/${pkgname}-${pkgver}.tgz"
# Remove references to pkgdir
find "${pkgdir}" -name package.json -exec sed -i "s|${pkgdir}||g" {} +
# Fix permissions
find "${pkgdir}/usr" -type d -exec chmod 755 {} +
# License
local _moddir="${pkgdir}/usr/lib/node_modules/@ilyasturki/${pkgname}"
install -Dm644 "${_moddir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
# Shell completions
local _bindir="${_moddir}/bin"
node "${_bindir}/dircmp.js" completions bash | install -Dm644 /dev/stdin "${pkgdir}/usr/share/bash-completion/completions/dircmp"
node "${_bindir}/dircmp.js" completions zsh | install -Dm644 /dev/stdin "${pkgdir}/usr/share/zsh/site-functions/_dircmp"
node "${_bindir}/dircmp.js" completions fish | install -Dm644 /dev/stdin "${pkgdir}/usr/share/fish/vendor_completions.d/dircmp.fish"
}
|