blob: 12ca79fac3ae1a72f3dd666c18cd5bc2ffcdf1a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Anna <morganamilo@gmail.com>
# Maintainer: E5ten <e5ten.arch@gmail.com>
# Maintainer: Parker Reed <parker.l.reed@gmail.com>
# Maintainer: Stephanie Wilde-Hobbs <steph@rx14.co.uk>
# Contributor: Cayde Dixon <me@cazzar.net>
# Contributor: Anthony Anderson <aantony4122@gmail.com>
pkgname=discord-canary
pkgver=0.0.114
pkgrel=1
pkgdesc="All-in-one voice and text chat for gamers that's free and secure."
arch=('x86_64')
url='https://discordapp.com/'
provides=('discord-canary')
license=('custom')
makedepends=('asar')
depends=('gtk3' 'libnotify' 'libxss' 'glibc' 'alsa-lib' 'nspr' 'nss' 'xdg-utils' 'libcups')
optdepends=('libpulse: For pulseaudio support'
'noto-fonts-emoji: Google font for emoji support.'
'ttf-symbola: Font for emoji support.'
'noto-fonts-cjk: Font for special characters such as /shrug face.')
source=("https://dl-canary.discordapp.net/apps/linux/${pkgver}/${pkgname}-${pkgver}.tar.gz"
'LICENSE'
"${pkgname}.sh")
sha256sums=('8130c6240f4b027eabf7fa0e8cf10485cb9db5c45a1832c0bf5947499c247c48'
'9be5f85421c9094c390c25bf1f45157c3c8dcf592feb8acb0810a61f11d80b90'
'7119a3345162d39bf86813d19546b488a1bdba12d38c3d39749f86bd587f0a0c')
package() {
# Patch
rm -rf "${srcdir}/unpack"
mkdir "${srcdir}/unpack"
asar extract "${srcdir}/DiscordCanary/resources/app.asar" "${srcdir}/unpack"
sed -i 's/emit..update-manually.*)/emit("update-not-available")/' "${srcdir}/unpack/app_bootstrap/hostUpdater.js"
asar pack "${srcdir}/unpack" "${srcdir}/DiscordCanary/resources/app.asar"
# Install the main files.
install -d "${pkgdir}/opt/${pkgname}"
cp -a "${srcdir}/DiscordCanary/." "${pkgdir}/opt/${pkgname}"
# Desktop Entry
install -Dm644 "${pkgdir}/opt/${pkgname}/${pkgname}.desktop" -t "${pkgdir}/usr/share/applications"
sed -i "s%share/${pkgname}/DiscordCanary%bin/${pkgname}%" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
# Wrapper script enabling --no-sandbox
install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
# Create symbolic link to the icon
install -d "${pkgdir}/usr/share/pixmaps"
ln -s "/opt/${pkgname}/discord.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
# License
install -Dm644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|