blob: ed237b0ba01c3fa5f95e450651a72097c566a330 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Contributor: Morgan <morganamilo@archlinux.org>
pkgname=discord-canary
_pkgname=DiscordCanary
pkgver=0.0.389
pkgrel=1
pkgdesc="All-in-one voice and text chat for gamers - alpha build"
arch=('x86_64')
url='https://discordapp.com'
license=('custom')
options=(!strip)
depends=('libnotify' 'libxss' 'nspr' 'nss' 'gtk3')
optdepends=('libpulse: Pulseaudio support'
'xdg-utils: Open files')
source=("https://dl-canary.discordapp.net/apps/linux/$pkgver/$pkgname-$pkgver.tar.gz"
'LICENSE.html::https://discordapp.com/terms'
'OSS-LICENSES.html::https://discordapp.com/licenses')
sha512sums=('5dcf8024ed2cf823b813f9bed57e6be42c1edba891e27079b4d866bbe74a46f32c2fd6a9479fba80097edfd79690fcfbb2962809e13770f89fc2b5e8d595abb6'
'SKIP'
'SKIP')
prepare() {
cd $_pkgname
sed -i "s|Exec=.*|Exec=/usr/bin/$pkgname|" $pkgname.desktop
echo 'Path=/usr/bin' >> $pkgname.desktop
}
package() {
install -d "$pkgdir"/opt/$pkgname
cp -a $_pkgname/. "$pkgdir"/opt/$pkgname
chmod 755 "$pkgdir"/opt/$pkgname/$_pkgname
rm "$pkgdir"/opt/$pkgname/postinst.sh
install -d "$pkgdir"/usr/{bin,share/{pixmaps,applications}}
ln -s /opt/$pkgname/$_pkgname "$pkgdir"/usr/bin/$pkgname
ln -s /opt/$pkgname/discord.png "$pkgdir"/usr/share/pixmaps/$pkgname.png
ln -s /opt/$pkgname/$pkgname.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop
# setuid on chrome-sandbox
chmod u+s "$pkgdir"/opt/$pkgname/chrome-sandbox
install -Dm644 LICENSE.html "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.html
install -Dm644 OSS-LICENSES.html "$pkgdir"/usr/share/licenses/$pkgname/OSS-LICENSES.html
}
|