blob: faf881f3567282b973c4256325088ef08e17b90f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Tim Schumacher <timschumi@gmx.de>
# Contributor: Filipe Laíns (FFY00) <lains@archlinux.org>
pkgname=discord-ptb
_pkgname=DiscordPTB
pkgver=0.0.18
pkgrel=1
pkgdesc="All-in-one voice and text chat for gamers that's free and secure. - Public Test Build"
arch=('x86_64')
url='https://discordapp.com'
license=('custom')
depends=('libnotify' 'libxss' 'nspr' 'nss'
'opera-ffmpeg-codecs' 'libegl' 'libgles') # Replacements
optdepends=('libpulse: Pulseaudio support'
'xdg-utils: Open files')
source=("https://dl-ptb.discordapp.net/apps/linux/$pkgver/$pkgname-$pkgver.tar.gz"
'LICENSE'
'OSS-LICENSES::https://discordapp.com/licenses')
sha512sums=('ceeed435384e94bb0f44963ca6a641c7787ae4d76141aa30a86783c992d9d9beaa84563ea66df3589dc3b5f6a58eeeafab910b2661d9132e18a2eded4a61b19b'
'2478ed8c0c3f086cfa9e6f8a7f8264a3a0f20364b940f888efe7a695f54f103523547e9b95db046776d7d9c820447436fbf65e557daf583947a6bbef5620971d'
'SKIP')
prepare() {
cd $_pkgname
sed -i "s|Exec=.*|Exec=/usr/bin/$pkgname|" $pkgname.desktop
echo 'Path=/usr/bin' >> $pkgname.desktop
}
package() {
# Install the app
install -d "$pkgdir"/opt/$pkgname
cp -a $_pkgname/. "$pkgdir"/opt/$pkgname
chmod 755 "$pkgdir"/opt/$pkgname/$_pkgname
rm "$pkgdir"/opt/$pkgname/postinst.sh
install -d "$pkgdir"/usr/{bin,share/{pixmaps,applications}}
ln -s /opt/$pkgname/$_pkgname "$pkgdir"/usr/bin/$pkgname
ln -s /opt/$pkgname/discord.png "$pkgdir"/usr/share/pixmaps/$pkgname.png
ln -s /opt/$pkgname/$pkgname.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop
# Replacement symlinks
ln -sf /usr/lib/opera/lib_extra/libffmpeg.so "$pkgdir"/opt/$pkgname/libffmpeg.so
ln -sf /usr/lib/libEGL.so "$pkgdir"/opt/$pkgname/libEGL.so
ln -sf /usr/lib/libGLESv2.so "$pkgdir"/opt/$pkgname/libGLESv2.so
ln -sf /usr/lib/libEGL.so "$pkgdir"/opt/$pkgname/swiftshader/libEGL.so
ln -sf /usr/lib/libGLESv2.so "$pkgdir"/opt/$pkgname/swiftshader/libGLESv2.so
# Licenses
install -Dm 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
install -Dm 644 OSS-LICENSES "$pkgdir"/usr/share/licenses/$pkgname/OSS-LICENSES
# Cut HTML from licenses file (remove lines 1-34 and everything from '">' to EOF)
sed -i '1,34d;/^">/,$d' "$pkgdir"/usr/share/licenses/$pkgname/OSS-LICENSES
}
|