blob: 45f72f5d243c56cc14804faacaf11b2e9e7b7c7e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: graysky <graysky AT archlinux DOT us>
pkgname=distccd-x86_64
arch=(armv7h aarch64)
_date=20191105
# inspect source tarball under $name/share/gcc-x.y.z
pkgver=9.2.0
pkgrel=3
license=('GPL' )
url="https://archlinuxarm.org/wiki/Distcc_Cross-Compiling"
pkgdesc="Toolchain for x86_64 builds on Arch ARM volunteers via distcc"
depends=('distcc')
options=('libtool' 'emptydirs' '!strip')
source=("http://repo-ck.com/PKG_source/x-tools86-armv7h-$_date.tar.zst"{,.sig}
"http://repo-ck.com/PKG_source/x-tools86-aarch64-$_date.tar.zst"{,.sig}
distccd-x86_64.{service,config}
)
noextract=("x-tools86-armv7h-$_date.tar.zst"
"x-tools86-aarch64-$_date.tar.zst")
backup=(etc/conf.d/distccd-x86_64)
install=readme.install
validpgpkeys=(
'4E22BB637E26407D5DEE550988A032865EE46C4C' # graysky
)
sha256sums=('90071322f03cabb95a2ea5e4c01fd55f5991acce02014074598097e5c06070d4'
'SKIP'
'95455060d212b52a805fb3da7ad3319a172c96c6e52583cd6222830220411f34'
'SKIP'
'23e791054de2b2599699482fdd880066c9d03758f9e38eb4634dc571cb90959e'
'ea406b82e10b7084192d0a480ec24ee889a6a592ea3e339dc81cf3a6f1058bf9')
package() {
# install symlink to distccd
install -d "${pkgdir}/usr/bin"
ln -sf /usr/bin/distccd "${pkgdir}/usr/bin/distccd-x86_64"
# install whitelist for toolchain new for v3.3
install -d "${pkgdir}/usr/lib/distcc"
_targets=(c++ cc clang clang++ cpp g++ gcc)
for bin in "${_targets[@]}"; do
ln -sf ../../distcc "${pkgdir}/usr/lib/distcc/x86_64-pc-linux-gnu-$bin"
done
# install service and config
install -Dm644 "${srcdir}/distccd-x86_64.service" \
"${pkgdir}/usr/lib/systemd/system/distccd-x86_64.service"
install -Dm644 "${srcdir}/distccd-x86_64.config" \
"${pkgdir}/etc/conf.d/distccd-x86_64"
# copy in toolchain
install -d "${pkgdir}/opt"
bsdtar -xf "${srcdir}/x-tools86-$CARCH-$_date.tar.zst" -C "${pkgdir}/opt/"
}
|