blob: 3c59885a97c4c9a649eb8ad77a63d4f84a3019cc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Contributor: Johannes Dewender arch at JonnyJD dot net
pkgname=distro-info
_python=python2
pkgver=0.11
pkgrel=1
pkgdesc="provides information about the distributions' releases"
arch=('i686' 'x86_64')
url="http://packages.debian.org/sid/distro-info"
license=('MIT')
depends=('distro-info-data')
makedepends=('shunit2' 'perl' 'python-distribute' 'python2-distribute' 'python-pylint')
provides=('python-distro-info' 'python2-distro-info' 'perl-distro-info')
conflicts=('python-distro-info' 'python2-distro-info' 'perl-distro-info')
options=(!emptydirs)
source=(http://ftp.debian.org/debian/pool/main/d/$pkgname/${pkgname}_$pkgver.tar.gz)
md5sums=('9256261319aea276310d6d3f2b042697')
build() {
cd "$srcdir/$pkgname-$pkgver"
sed -i -e 's/python3 setup.py/python2 setup.py/g' \
-e 's/ --install-layout=deb//g' \
Makefile
make
}
check() {
cd "$srcdir/$pkgname-$pkgver"
make test-commandline
make test-perl
cd python
# We don't want to test all installed python versions -> don't use "make test"
for pythonver in {python2,python}; do
$pythonver setup.py test
done
}
package() {
cd "$srcdir/$pkgname-$pkgver"
# vendor can currently be only ubuntu or debian
# with ubuntu you can build for PPA (with bzr-builddeb)
make DESTDIR="$pkgdir/" VENDOR="ubuntu" install
}
# vim:set ts=2 sw=2 et:
|