blob: d115104aa8812cc4926c63dd91c59e470aa7f5c3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Jonathan Liu <net147@gmail.com>
# Contributer: N30N <archlinux@alunamation.com>
pkgname=djv
pkgver=1.1.0
pkgrel=3
pkgdesc="Movie playback and image processing software for the film and computer animation industries"
url="http://djv.sourceforge.net/"
license=('BSD')
arch=('i686' 'x86_64')
depends=("desktop-file-utils" "ffmpeg" "glew" "libjpeg" "libpng" "libquicktime" "libtiff" "openexr" "qt5-base")
makedepends=("cmake" "portaudio" "qt5-tools")
options=("!docs")
install="${pkgname}.install"
source=("git://git.code.sf.net/p/djv/git#commit=44a063755e627c70498d948478e29ffc1d3f105d"
"ffmpeg.patch"
"${pkgname}_view.desktop")
md5sums=('SKIP'
'9544548cd8bd762233398b0cb8ea91cd'
'2668ad2635036f33ba615b5dc538b1cf')
prepare() {
cd git
sed -i '/enable_testing()/d' CMakeLists.txt
sed -i '/add_subdirectory(tests)/d' CMakeLists.txt
sed -i 's/set(djvPackageThirdParty true)/set(djvPackageThirdParty false)/' CMakeLists.txt
patch -Np1 -i "${srcdir}/ffmpeg.patch"
}
build() {
[[ -d build ]] && rm -r build
mkdir build && cd build
cmake -D CMAKE_INSTALL_PREFIX:PATH=/usr ../git
make
}
package() {
cd build
make DESTDIR=${pkgdir} install
install -D -m644 {"${srcdir}","${pkgdir}/usr/share/applications"}/"${pkgname}_view.desktop"
install -D -m644 "${srcdir}/git/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -D -m644 "${srcdir}/git/lib/djvViewLib/images/projector32x32.png" "${pkgdir}/usr/share/pixmaps/djv_view.png"
}
# vim:set ts=2 sw=2 et:
|