PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Morgana <morganamilo@gmail.com>

pkgname=dl-desktop-git
_pkgname=dl-desktop
pkgver=r259.0275138
pkgrel=1
pkgdesc="Desktop client for Duolingo, using Electron"
arch=(x86_64)
url="https://github.com/hmlendea/dl-desktop"
license=('GPL')
depends=('gtk2' 'libxss' 'nss' 'nspr' 'libxtst' 'alsa-lib')
makedepends=('npm' 'git')
source=("git+https://github.com/hmlendea/dl-desktop")
md5sums=("SKIP")

pkgver() {
  cd "dl-desktop"
  #git describe --tags | sed 's/-/+/g'
   printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}


build() {
	cd ${srcdir}/${_pkgname}
	npm install
	npm run build -- --dir
}

package() {
	cd ${srcdir}/${_pkgname}

	install -d "${pkgdir}/opt/${_pkgname}"
	cp -a "${srcdir}/${_pkgname}/dist/linux-unpacked/." "${pkgdir}/opt/${_pkgname}"

	chmod 755 "${pkgdir}/opt/${_pkgname}/${_pkgname}"

	install -d "${pkgdir}/usr/bin"
	ln -s "/opt/${_pkgname}/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"

	install -d "${pkgdir}/usr/share/applications"
	mv ro.go.hmlendea.DL-Desktop.desktop dl-desktop.desktop
	install -Dm644 "${_pkgname}.desktop" "${pkgdir}/usr/share/applications"
	install -Dm644 "icon.png" "${pkgdir}/usr/share/icons/ro.go.hmlendea.DL-Desktop.png"
	install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"	
	install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"	
}