PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: pingplug <pingplug@foxmail.com>
# Contributor: perlawk

pkgname=dlib
_pkgname=dlib
pkgver=19.9
pkgrel=1
pkgdesc="Dlib is a general purpose cross-platform C++ library designed using contract programming and modern C++ techniques."
arch=('x86_64')
url="http://www.dlib.net/"
license=('Boost Software License')
makedepends=('cmake')
optdepends=('blas: for BLAS support'
            'cuda: for CUDA support'
            'cudnn: for CUDNN support'
            'giflib: for GIF support'
            'lapack: for LAPACK support'
            'libjpeg-turbo: for JPEG support'
            'libpng: for PNG support'
            'neon: for neon support'
            'sqlite: for sqlite support')
source=(https://downloads.sourceforge.net/project/dclib/${_pkgname}/v${pkgver}/${_pkgname}-${pkgver}.tar.bz2)
sha512sums=('3cbd2b7d2cad2e494a14e9f19469e6ab33263ad87aa32e6f65de689ebfb395277fd5d5c3fd4a510cc16d3a8768d9685652c8378fcde0ceec5234363ab492b473')

build() {
    cd "${srcdir}"
    mkdir -p build && cd build
    cmake \
        -DCMAKE_INSTALL_PREFIX:PATH=/usr \
        -DCMAKE_INSTALL_LIBDIR:PATH=/usr/lib \
        -DBUILD_SHARED_LIBS:BOOL=ON \
        -DUSE_AVX_INSTRUCTIONS:BOOL=ON \
        -DUSE_SSE2_INSTRUCTIONS:BOOL=ON \
        -DUSE_SSE4_INSTRUCTIONS:BOOL=ON \
        -DCUDA_HOST_COMPILER='/usr/bin/cc-6' \
        -DCMAKE_BUILD_TYPE=Release \
        "../${_pkgname}-${pkgver}"
    make
}

package() {
    cd "${srcdir}/build"
    make DESTDIR=${pkgdir} install
    install -Dm644 "../${_pkgname}-${pkgver}/dlib/LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}