blob: 25c7bdddf7f8ca00bbfd5ba47e8c4e7f5bfe7b2d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Adrian Perez <aperez@igalia.com>
pkgname='dmon'
pkgver='0.4.4'
pkgrel='1'
pkgdesc='Toolset for daemonizing and supervising processes'
arch=('i686' 'x86_64' 'arm')
url='https://github.com/aperezdc/dmon'
license=('MIT')
depends=('glibc')
makedepends=('make' 'gnupg')
validpgpkeys=('91C559DBE4C9123B')
source=("git+https://github.com/aperezdc/dmon.git#tag=v${pkgver}"
"git+https://github.com/aperezdc/wheel.git")
sha1sums=('SKIP' 'SKIP')
_checktag () {
local -a line
while read -r -a line ; do
if [[ ${line[1]} = GOODSIG && ${line[2]} = ${validpgpkeys[0]} ]] ; then
return 0
fi
done < <( git verify-tag "v${pkgver}" --raw 2>&1 )
return 1
}
prepare () {
cd dmon
git submodule init
git config submodule.wheel.url "${srcdir}/wheel"
git submodule update
if ! git verify-tag "v${pkgver}" || ! _checktag ; then
exit 42
fi
}
build() {
cd dmon
make MULTICALL=1 prefix=/usr
}
package() {
cd dmon
make MULTICALL=1 prefix=/usr DESTDIR="${pkgdir}/" install
install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgver}/README"
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|