blob: 1f5dee31a9f3e60a6a158cc0620b09802199e5a6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
pkgname=dnf
pkgver=3.0.2
pkgrel=1
pkgdesc="Package manager forked from Yum, using libsolv as a dependency resolver"
arch=('any')
url="https://github.com/rpm-software-management/$pkgname"
license=('GPL2' 'GPL')
depends=('libdnf>=0.14.0' 'libcomps>=0.1.8' 'libmodulemd>=1.4.0'
'librepo>=1.9.0'
'python' 'python-gobject' 'python-gpgme' 'python-iniparse'
'python-smartcols'
'rpm-org')
makedepends=('bash-completion' 'cmake' 'python-sphinx')
checkdepends=('python-nose')
backup=("etc/$pkgname/automatic.conf"
"etc/$pkgname/$pkgname.conf")
source=("$url/archive/$pkgver/$pkgname-$pkgver.tar.gz"
"$pkgname-3.0.1-fallback-to-getuid-if-audit-is-disabled.patch")
md5sums=('111db3467c89a35c66442cf0def42333'
'51bbd2fd1ab2c11057c833adecb8b5fa')
prepare() {
cd "$pkgname-$pkgver"
rm -rf build
mkdir build
patch -p1 < "$srcdir/$pkgname-3.0.1-fallback-to-getuid-if-audit-is-disabled.patch"
}
build() {
cd "$pkgname-$pkgver"/build
cmake -DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DPYTHON_DESIRED=3 \
..
make
make doc-man
}
# Tests seem to need a non-empty RPM database installed on the system
#check() {
# cd "$pkgname-$pkgver"/build
# make ARGS="-V" test
#}
package() {
cd "$pkgname-$pkgver"/build
make DESTDIR="$pkgdir/" install
rm "$pkgdir/usr/share/man/man8/yum.8" \
"$pkgdir/usr/share/man/man5/yum.conf.5"
ln -s $pkgname-3 "$pkgdir/usr/bin/$pkgname"
ln -s $pkgname-automatic-3 "$pkgdir/usr/bin/$pkgname-automatic"
install -Dp -m644 ../README.rst "$pkgdir/usr/share/doc/$pkgname/README.rst"
}
# vim: set ft=sh ts=4 sw=4 noet:
|