blob: 2a0153d2f7e86338f7bbc904463b10bd7874b237 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
pkgname=dnf-plugins-core
pkgver=4.6.0
pkgrel=1
pkgdesc="Core DNF Plugins"
arch=('any')
url="https://github.com/rpm-software-management/$pkgname"
license=('GPL-2.0-or-later')
depends=('dnf>=4.19.0' 'python')
makedepends=('cmake>=3.13' 'python-sphinx')
checkdepends=('python-dbus' 'python-systemd')
optdepends=('createrepo_c: for local plugin'
'python-dateutil: for changelog plugin'
'python-dbus: for needs-restarting plugin'
'python-distro: for copr plugin'
'python-systemd: for system-upgrade plugin')
conflicts=('dnf-plugins-extras<4.1.0')
backup=('etc/dnf/plugins/copr.conf'
'etc/dnf/plugins/debuginfo-install.conf'
'etc/dnf/plugins/local.conf'
'etc/dnf/plugins/pre-transaction-actions.conf'
'etc/dnf/plugins/post-transaction-actions.conf'
'etc/dnf/plugins/versionlock.conf'
'etc/dnf/plugins/versionlock.list')
options=('!emptydirs')
source=("$url/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('8fe617ff5966006ef94b4cb07807ea3c68b8be5b5993c2fa0c639408851b1456')
prepare() {
cd "$pkgname-$pkgver"
# sphinx-build-3 does not exist on Arch Linux,
# use sphinx-build instead
sed -e 's/sphinx-build-3/sphinx-build/' \
-i doc/CMakeLists.txt
}
build() {
cd "$pkgname-$pkgver"
cmake -B build \
-DCMAKE_INSTALL_PREFIX=/usr \
-DPYTHON_DESIRED=3
cmake --build build
cmake --build build --target doc-man
}
check() {
cd "$pkgname-$pkgver"
# Tests fail with non-english locales
LC_ALL=C.UTF-8 ctest --test-dir build --output-on-failure
}
package() {
cd "$pkgname-$pkgver"
DESTDIR="$pkgdir" cmake --install build
install -Dp -m644 README.rst "$pkgdir/usr/share/doc/$pkgname/README.rst"
# Conflict with yum-utils
rm "$pkgdir/usr/share/man/man1/debuginfo-install.1" \
"$pkgdir/usr/share/man/man1/needs-restarting.1" \
"$pkgdir/usr/share/man/man1/package-cleanup.1" \
"$pkgdir/usr/share/man/man1/repodiff.1" \
"$pkgdir/usr/share/man/man1/repo-graph.1" \
"$pkgdir/usr/share/man/man1/repoclosure.1" \
"$pkgdir/usr/share/man/man1/repomanage.1" \
"$pkgdir/usr/share/man/man1/reposync.1" \
"$pkgdir/usr/share/man/man1/yum-builddep.1" \
"$pkgdir/usr/share/man/man1/yum-changelog.1" \
"$pkgdir/usr/share/man/man1/yum-config-manager.1" \
"$pkgdir/usr/share/man/man1/yum-debug-dump.1" \
"$pkgdir/usr/share/man/man1/yum-debug-restore.1" \
"$pkgdir/usr/share/man/man1/yumdownloader.1" \
"$pkgdir/usr/share/man/man1/yum-groups-manager.1" \
"$pkgdir/usr/share/man/man1/yum-utils.1" \
"$pkgdir/usr/share/man/man5/yum-versionlock.conf.5" \
"$pkgdir/usr/share/man/man8/yum-copr.8" \
"$pkgdir/usr/share/man/man8/yum-versionlock.8"
}
# vim: set ft=sh ts=4 sw=4 noet:
|