blob: 9eb622c63ab89975138b4325e9127b15fed76bfe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Mario Finelli <mario at finel dot li>
pkgname=dnglab
pkgver=0.7.1
pkgrel=1
pkgdesc="Camera RAW to DNG file format converter"
arch=(x86_64)
url=https://github.com/dnglab/dnglab
license=(LGPL-2.1-only)
depends=(glibc gcc-libs)
makedepends=(cargo)
source=($url/archive/v$pkgver/$pkgname-$pkgver.tar.gz)
sha256sums=('9a62c63a0775c946ccc378dbbc0f9206f593659f2f998cfb66bf6a0f64487e2f')
prepare() {
cd $pkgname-$pkgver
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd $pkgname-$pkgver
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release
}
check() {
cd $pkgname-$pkgver
export RUSTUP_TOOLCHAIN=stable
cargo test --all --release --frozen
}
package() {
cd $pkgname-$pkgver
install -Dm0755 target/release/dnglab "$pkgdir/usr/bin/dnglab"
install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname/" *.md
install -Dm0644 -t "$pkgdir/usr/share/man/man1/" bin/dnglab/manpages/*.1
install -Dm0644 bin/dnglab/completions/dnglab.bash \
"$pkgdir/usr/share/bash-completion/completions/dnglab"
install -Dm0644 bin/dnglab/completions/dnglab.fish \
"$pkgdir/usr/share/fish/vendor_completions.d/dnglab.fish"
install -Dm0644 bin/dnglab/completions/_dnglab \
"$pkgdir/usr/share/zsh/site_functions/_dnglab"
}
# vim: set ts=2 sw=2 et:
|