blob: 0b017aa18f359bc666ecd278f4b4e106585eac87 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer: Sherlock Holo <sherlockya(at)gmail.com>
# Contributors: Ariel AxionL <i [at] axionl [dot] me>
pkgbase='dns-over-https'
pkgname=('dns-over-https-client' 'dns-over-https-server')
pkgver=2.1.2
pkgrel=1
pkgdesc="Client and server software to query DNS over HTTPS, using Google DNS-over-HTTPS protocol"
url="https://github.com/m13253/dns-over-https"
arch=('x86_64' 'i686' 'armv7h')
license=('MIT')
makedepends=('go' 'git')
source=("$url/archive/v$pkgver.tar.gz")
sha256sums=('b94c57adc888d0bc773137d9f9b01bb459ed8832a2129e0096a3b0ccf7053615')
build() {
mkdir -p ${srcdir}/go/src
export GOPATH="${srcdir}/go"
cd ${srcdir}/${pkgbase}-${pkgver}
sed -i 's/\/local//g' systemd/doh-client.service
sed -i 's/\/local//g' systemd/doh-server.service
go mod download
# build client
go build -gcflags "all=-trimpath=${PWD}" -asmflags "all=-trimpath=${PWD}" -ldflags "-w -s -extldflags ${LDFLAGS}" -v -o client ./doh-client
# build server
go build -gcflags "all=-trimpath=${PWD}" -asmflags "all=-trimpath=${PWD}" -ldflags "-w -s -extldflags ${LDFLAGS}" -v -o server ./doh-server
# clean build cache
chmod 777 -R $GOPATH/pkg/mod
rm -rf $GOPATH/pkg/mod
}
package_dns-over-https-client() {
# Backup and conflicts
backup=('etc/dns-over-https/doh-client.conf')
conflicts=('dns-over-https' 'dns-over-https-client-git')
provides=('dns-over-https-client')
# Install binary
install -Dm755 ${srcdir}/${pkgbase}-${pkgver}/client ${pkgdir}/usr/bin/doh-client
# Install others
cd ${srcdir}/${pkgbase}-${pkgver}
install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
install -Dm644 doh-client/doh-client.conf ${pkgdir}/etc/dns-over-https/doh-client.conf
install -Dm644 systemd/doh-client.service ${pkgdir}/usr/lib/systemd/system/doh-client.service
install -Dm755 NetworkManager/dispatcher.d/doh-client ${pkgdir}/etc/NetworkManager/dispatcher.d/doh-client
}
package_dns-over-https-server() {
# Backup and conflicts
optdepends=('dns-over-https-client')
backup=('etc/dns-over-https/doh-server.conf')
conflicts=('dns-over-https-server-git')
provides=('dns-over-https-server')
replaces=('dns-over-https')
# Install binary
install -Dm755 ${srcdir}/${pkgbase}-${pkgver}/server ${pkgdir}/usr/bin/doh-server
# Install others
cd ${srcdir}/${pkgbase}-${pkgver}
install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
install -Dm644 doh-server/doh-server.conf ${pkgdir}/etc/dns-over-https/doh-server.conf
install -Dm644 systemd/doh-server.service ${pkgdir}/usr/lib/systemd/system/doh-server.service
install -Dm755 NetworkManager/dispatcher.d/doh-server ${pkgdir}/etc/NetworkManager/dispatcher.d/doh-server
}
# vim:set ts=4 sw=4 et:
|