blob: fe719e46ce0068692efa1e53393ec156461a5b81 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Ben Wolsieffer <benwolsieffer@gmail.com>
_github_url=https://github.com/lopsided98/dnsupdate
pkgname=dnsupdate
pkgver=0.3
pkgrel=2
pkgdesc="A modern and flexible dynamic DNS client"
arch=('any')
url="${_github_url}"
license=('GPL3')
depends=('python-requests' 'python-yaml')
makedepends=(
'git'
'python-setuptools'
'python-sphinx'
'python-sphinx-argparse'
'python-commonmark'
)
optdepends=(
'python-beautifulsoup4: router address scraping'
'python-netifaces: local interface address support'
)
conflicts=('dnsupdate-git')
source=(${pkgname}::git+${_github_url}.git#tag=${pkgver})
sha256sums=('SKIP')
build() {
cd "${srcdir}/${pkgname}"
python setup.py build
# Build man pages
#python setup.py build_docs -b man
# The previous line is broken in 0.3, because sphinx changed its internals
sphinx-build -b man docs build/docs/man
}
check() {
cd "${srcdir}/${pkgname}"
python setup.py test
}
package() {
cd "${srcdir}/${pkgname}"
python setup.py install --skip-build --root="${pkgdir}" --optimize=1
install -Dm644 dnsupdate.service -t "${pkgdir}/usr/lib/systemd/system/"
cd build/docs/man
install -Dm644 "dnsupdate.1" -t "${pkgdir}/usr/share/man/man1/"
install -Dm644 "dnsupdate.5" -t "${pkgdir}/usr/share/man/man5/"
}
# vim:set ts=4 sw=4 et:
|