blob: a08a558f3cdf16ee4241fc7016fb6992bbd81b89 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Thiago Perrotta <echo dGhpYWdvcGVycm90dGE5NUBnbWFpbC5jb20K | base64 -d >
# Maintainer: Macxcool <macx cool at tuta nota dot com>
pkgname=docfetcher
_name=DocFetcher
pkgver=1.1.27
pkgrel=2
pkgdesc="A java open source desktop search application"
arch=('i686' 'x86_64')
url="http://${pkgname}.sourceforge.net/"
license=('EPL')
depends=('java-runtime>17')
makedepends=('unzip')
optdepends=('gtk3: GTK3-based interface')
_downloadfile="${_name}-${pkgver}-Linux-64bit-NonPortable"
source=("https://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/${_downloadfile}.zip"
'docfetcher'
'docfetcher.desktop')
sha256sums=('10a5831b384330a45849ddcf1e2e22d8c9e0669d23da45a74c423fc673bab267'
'd49d1c1327b72345040c76ae510a3eaa520c82dd5c43f2a6e597f1c984b55c50'
'878ea6e2188733f13a7580606fef290ae5b547b814b33efcd61f8cef79b76b61')
prepare() {
# Change path for config, cache, and where SWT libraries will be unpacked. See the following link:
# http://docfetcher.sourceforge.net/wiki/doku.php?id=faq
cd "${srcdir}/${_downloadfile}/misc/"
sed -i 's_#settings=C:/path/to/settings/folder_settings=${user.home}/.config/docfetcher_' paths.txt
sed -i 's_#indexes=C:/path/to/indexes/folder_indexes=${user.home}/.cache/docfetcher_' paths.txt
sed -i 's_#swt=C:/path/to/swt/folder_swt=${user.home}/.local/share/docfetcher_' paths.txt
# Now make sure that the java path is correct
cd "${srcdir}/${_downloadfile}"
sed -i 's_./jre/bin/java_/usr/bin/java_' DocFetcher.sh
}
package() {
cd "${srcdir}/${_downloadfile}/"
# Executable
install -Dm 755 "../${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
# .desktop file
install -Dm 755 "../${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
# Copy files to destination
prefix="${pkgdir}/usr/share/${pkgname}"
for folder in help img lang misc lib py4j; do
install -d "${prefix}/$folder"
cp -a "./${folder}" "${prefix}"
done
# Make sure dir and file permissions are sane
find "${prefix}" -type d -exec chmod 755 {} +
find "${prefix}" -type f -exec chmod 644 {} +
# Put the executables in place
install -m 755 DocFetcher.sh "${prefix}"
install -m 755 docfetcher-daemon-linux "${prefix}"
install -m 755 search.py "${prefix}"
# Copy the icons
for res in 16 24 32 48 64 128; do
install -Dm 644 "img/docfetcher${res}.png" "${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/docfetcher.png"
done
}
|