blob: f506bb124fdf42c347f581efa4176516ad2e15f3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Maintainer: Mike Javorski
# Contributor: Sébastien "Seblu" Luttringer
pkgname=docker-bin
pkgver=20.10.9
# must use commit sha as currently not tagged with 20.10+ versions
_packaging_version=1c1cb918d8cf84f321bab7cb9739c221fe4f3ed7
_buildx_version=v0.6.3
pkgrel=2
pkgdesc='Pack, ship and run any application as a lightweight container, using official binaries'
arch=('x86_64')
url='https://www.docker.com/'
license=('Apache')
provides=('docker' 'docker-ce')
conflicts=('docker' 'docker-ce' 'docker-git')
depends=('bridge-utils' 'iproute2' 'device-mapper' 'sqlite' 'systemd' 'libseccomp' 'runc' 'containerd')
optdepends=('btrfs-progs: btrfs backend support'
'pigz: parallel gzip compressor support')
# don't strip binaries! A sha1 is used to check binary consistency.
options=('!strip')
source=(
"https://download.docker.com/linux/static/stable/x86_64/docker-${pkgver}.tgz"
"https://download.docker.com/linux/static/stable/x86_64/docker-rootless-extras-${pkgver}.tgz"
"https://download.docker.com/linux/debian/dists/buster/pool/stable/amd64/docker-ce-cli_${pkgver}~3-0~debian-buster_amd64.deb"
"https://github.com/docker/buildx/releases/download/${_buildx_version}/buildx-${_buildx_version}.linux-amd64"
"https://raw.githubusercontent.com/docker/docker-ce-packaging/${_packaging_version}/systemd/docker.socket"
"https://raw.githubusercontent.com/docker/docker-ce-packaging/${_packaging_version}/systemd/docker.service"
"https://raw.githubusercontent.com/moby/moby/v${pkgver}/contrib/syntax/nano/Dockerfile.nanorc"
"https://raw.githubusercontent.com/moby/moby/v${pkgver}/contrib/udev/80-docker.rules"
"docker.sysusers"
)
sha256sums=('caf74e54b58c0b38bb4d96c8f87665f29b684371c9a325562a3904b8c389995e'
'5c14e2e105cc5355e34f7173792f12d9c26aa4aac38f4b24f7cde7f9b0bfbe73'
'07d6697fc25b7b5686f8f924388da8bc60a47d6ad4526318b9fe3a9b1d2619e2'
'8dbc69a27afbc668e5d9fcda0e6d8334c1716e0ea6bd4d22ba3a32a53c3c834b'
'caf98bf39fb8621fb955476567a38b8a6b35bab2dccd8a29a16da23d4bb99450'
'ed2ebb93d4bb3a30b5ad214d2ea5d467e714928d4fbf077e2a77dce758c0fa60'
'3b1bd816a4a029ac048be7703a72a69ff44c531ead443d573e04f29d812594f1'
'863aa0504a0ce84641e95ea29fae80c14c5a64c62b336149c3b7c5795b90a157'
'a7a4b52000ed38ead62665eec9ed2366a4f763d61977ebd5414b041ff1c3d415')
prepare() {
mkdir cli
msg2 'Extracting CLI package'
bsdtar -xf data.tar.xz -C cli/
}
package() {
cd $srcdir/docker
# docker-proxy
install -Dm755 'docker-proxy' "$pkgdir/usr/bin/docker-proxy"
# docker-init
install -Dm755 'docker-init' "$pkgdir/usr/bin/docker-init"
# docker binary
install -Dm755 'docker' "$pkgdir/usr/bin/docker"
install -Dm755 'dockerd' "$pkgdir/usr/bin/dockerd"
cd $srcdir/docker-rootless-extras
# rootless docker support
install -Dm755 'dockerd-rootless-setuptool.sh' "$pkgdir/usr/bin/dockerd-rootless-setuptool.sh"
install -Dm755 'dockerd-rootless.sh' "$pkgdir/usr/bin/dockerd-rootless.sh"
install -Dm755 'rootlesskit' "$pkgdir/usr/bin/rootlesskit"
install -Dm755 'rootlesskit-docker-proxy' "$pkgdir/usr/bin/rootlesskit-docker-proxy"
cd $srcdir/cli/usr/share
# completions
install -Dm644 'bash-completion/completions/docker' "$pkgdir/usr/share/bash-completion/completions/docker"
install -Dm644 'zsh/vendor-completions/_docker' "$pkgdir/usr/share/zsh/site-functions/_docker"
install -Dm644 'fish/vendor_completions.d/docker.fish' "$pkgdir/usr/share/fish/vendor_completions.d/docker.fish"
# man
install -dm755 "$pkgdir/usr/share/man"
cp -r man/man* "$pkgdir/usr/share/man"
cd $srcdir/
# buildx plugin
install -Dm755 "buildx-${_buildx_version}.linux-amd64" "$pkgdir/usr/lib/docker/cli-plugins/docker-buildx"
# systemd
install -Dm644 "docker.socket" "$pkgdir/usr/lib/systemd/system/docker.socket"
install -Dm644 "docker.service" "$pkgdir/usr/lib/systemd/system/docker.service"
install -Dm644 "docker.sysusers" "$pkgdir/usr/lib/sysusers.d/docker.conf"
# udev rules to hide docker's loopback devices from udisks, and thus from user desktops
install -Dm644 '80-docker.rules' "$pkgdir/usr/lib/udev/rules.d/80-docker.rules"
# nano syntax
install -Dm644 'Dockerfile.nanorc' "$pkgdir/usr/share/nano/Dockerfile.nanorc"
}
# vim:set ts=2 sw=2 et:
|