blob: 2ebf3e132ac305f323651fbbcd3ca7cbc6326d78 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
pkgname=doctave
pkgver=0.4.2
pkgrel=1
pkgdesc="A batteries-included developer documentation site generator"
arch=('x86_64')
url="https://www.doctave.com"
license=('MIT')
depends=('gcc-libs')
makedepends=('git' 'rust')
options=('!lto')
_commit='ad1888feb6bb7f4f043b76474b1df38b520c51c3'
source=("$pkgname::git+https://github.com/Doctave/doctave.git#commit=$_commit")
md5sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --tags
}
prepare() {
cd "$pkgname"
# download dependencies
cargo fetch --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$pkgname"
cargo build --frozen --release
}
check() {
cd "$pkgname"
cargo test --frozen
}
package() {
cd "$pkgname"
# binary
install -vDm755 -t "$pkgdir/usr/bin" target/release/doctave
# license
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
# documentation
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
}
|