blob: 3f5444ba5e65a6777de72eaa81ed3c8c94d99b46 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
pkgname=doctave
pkgver=0.4.1
pkgrel=1
pkgdesc="A batteries-included developer documentation site generator"
arch=('x86_64')
url="https://www.doctave.com"
license=('MIT')
depends=('gcc-libs')
makedepends=('git' 'rust')
_commit='bde7764bdbc66acc0db726126332db440959a492'
source=(
"$pkgname::git+https://github.com/Doctave/doctave.git#commit=$_commit"
'Cargo.lock'
)
sha512sums=('SKIP'
'cad78f16b0d1b05f03b1e3ef3cf2bfa2ba5095d0850ca424e4bc7e946a0fa8656c835224101c05b5a13bf23767351699f6988a9e53ebd6ab1a16a1228c23950d')
b2sums=('SKIP'
'5a981b59020045aff81ab12c396478546dbada470e09ecf908f046cbd9792e9ac26d59f273768ea46a5bb36db136860ac756e956916822143da8ca246e375a79')
pkgver() {
cd "$pkgname"
git describe --tags
}
prepare() {
cd "$pkgname"
cp -vf ../Cargo.lock .
# download dependencies
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$pkgname"
cargo build --frozen --release
}
check() {
cd "$pkgname"
cargo test --frozen
}
package() {
cd "$pkgname"
# binary
install -vDm755 -t "$pkgdir/usr/bin" target/release/doctave
# license
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
# documentation
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
}
|