blob: f8991600e8307ff3367bd398e819f4da91e5972a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Maintainer: Fabien LEFEBVRE <contact@d1ceward.com>
pkgname=dokku
pkgver=0.24.10
pkgrel=2
pkgdesc='Docker-powered PaaS that helps build and manage the lifecycle of applications'
arch=('any')
url='https://github.com/dokku/dokku'
license=('MIT')
depends=(
'bash-completion'
'bind'
'cpio'
'curl'
'docker'
'docker-image-labeler'
'dos2unix'
'git'
'go'
'gliderlabs-sigil'
'inetutils'
'herokuish'
'jq'
'man-db'
'netrc'
'net-tools'
'nginx'
'openbsd-netcat'
'parallel'
'plugn'
'procfile-util'
'rsyslog'
'sudo'
'sshcommand'
'unzip'
)
source=("https://github.com/dokku/dokku/archive/v$pkgver.zip"
"$pkgname.install"
"crontab_calls.patch"
"LICENSE")
sha256sums=('bed55e2f3d0b037a62599a528dace16083e528428277d8ab03a25041d8a7a2eb'
'dd7ca19339e18f8434ca74faeb994ae8446cb3ccf020e558eaa340ad1f72effe'
'88fae4d0578b9badaa91d1d4771952b4c7560ba2f56f4eda990034078a44431e'
'b1ac2fed5ac269fb7bbf651a3d37ef5fd56d2c33320e17cb6e23a22a93f5c046')
install="$pkgname.install"
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
export GOPATH="$srcdir/gopath"
cd "$pkgname-$pkgver"
# Fix issue on crontab calls with arch linux cron implementation
patch -p1 -i "${srcdir}/crontab_calls.patch"
# Add .core and build go plugins
for plugin in plugins/*; do
if [ -e "$plugin/Makefile" ]; then make -C $plugin build; fi
touch "$plugin/.core"
done
# Clean go plugins
for plugin in plugins/*; do
if [ -e "$plugin/Makefile" ]; then make -C $plugin src-clean; fi
done
}
package() {
# Install executable and license
install -Dm755 "$pkgname-$pkgver/dokku" "$pkgdir/usr/bin/dokku"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/dokku/LICENSE"
# Move all files in place
mkdir -p "$pkgdir/var/lib/dokku/core-plugins/available"
cp -R "$srcdir/$pkgname-$pkgver/plugins/." "$pkgdir/var/lib/dokku/core-plugins/available"
# Version
echo $pkgver > "$pkgdir/var/lib/dokku/VERSION"
}
|