blob: 760fa80647cb943f94635e5a8314f031ddaafc2e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Maintainer: Fabien LEFEBVRE <contact@d1ceward.com>
pkgname=dokku
pkgver=0.32.3
pkgrel=1
pkgdesc='Docker-powered PaaS that helps build and manage the lifecycle of applications'
arch=('any')
url='https://github.com/dokku/dokku'
license=('MIT')
depends=(
'bash-completion'
'bind'
'cpio'
'curl'
'docker'
'docker-compose'
'docker-container-healthchecker'
'docker-image-labeler'
'dos2unix'
'git'
'go'
'gliderlabs-sigil'
'herokuish'
'inetutils'
'jq'
'man-db'
'netrc'
'net-tools'
'nginx'
'openbsd-netcat'
'parallel'
'plugn'
'procfile-util'
'rsync'
'rsyslog'
'sudo'
'sshcommand'
'unzip'
)
source=("${url}/archive/v${pkgver}.zip"
"${pkgname}.install"
"systemd_calls.patch"
"LICENSE")
sha256sums=('5f47719310a33b9b3481337308b752cb305d8838f9179b0f93552bbb72bcba9e'
'c0b40188052a29dcfb3d8595a23a1a49adf6abc85c78ee99b530fae60cab932a'
'aec08deb0b1d466f37a0c76f93fc507d443ab8bd770cc0c1097ffeffa75cf9a4'
'b1ac2fed5ac269fb7bbf651a3d37ef5fd56d2c33320e17cb6e23a22a93f5c046')
install="${pkgname}.install"
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
export GOPATH="${srcdir}/gopath"
cd "${pkgname}-${pkgver}"
# Fix issue with invalid service manager call for arch linux
patch -p1 -i "${srcdir}/systemd_calls.patch"
# Add .core and build go plugins
for plugin in plugins/*; do
if [ -e "${plugin}/Makefile" ]; then make -C $plugin build; fi
touch "${plugin}/.core"
done
# Clean go plugins
for plugin in plugins/*; do
if [ -e "${plugin}/Makefile" ]; then make -C $plugin src-clean; fi
done
}
package() {
cd "${srcdir}"
# Install executable and license
install -Dm755 "${pkgname}-${pkgver}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
# Move all files in place
mkdir -p "${pkgdir}/var/lib/dokku/core-plugins/available"
cp -R "${srcdir}/${pkgname}-${pkgver}/plugins/." "${pkgdir}/var/lib/dokku/core-plugins/available"
# Version
echo $pkgver > "${pkgdir}/var/lib/dokku/VERSION"
}
|