blob: 49dc727461641a1b21bd873a3f68149863a25ec6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Lightning <sgsdxzy@gmail.com>
pkgbase=dolphin-emu-git
pkgname=('dolphin-emu-git' 'dolphin-emu-cli-git' 'dolphin-emu-qt-git')
pkgver=5.0.r27.64cf74a
pkgrel=1
pkgdesc='A GameCube / Wii / Triforce emulator'
arch=('x86_64')
url='http://www.dolphin-emu.org/'
license=('GPL')
depends=('bluez-libs' 'enet' 'ffmpeg' 'libao' 'libevdev' 'mbedtls' 'miniupnpc'
'openal' 'portaudio' 'soundtouch' 'xdg-utils' 'wxgtk')
makedepends=('cmake' 'git' 'qt5-base')
optdepends=('pulseaudio: PulseAudio backend')
options=('!emptydirs')
source=('dolphin-emu::git+https://github.com/dolphin-emu/dolphin.git')
sha256sums=('SKIP')
pkgver() {
cd dolphin-emu
git describe | sed 's/-/.r/; s/-g/./'
}
prepare() {
cd dolphin-emu
if [[ -d build ]]; then
rm -rf build
fi
mkdir build
}
build() {
cd dolphin-emu/build
cmake .. \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DCMAKE_CXX_FLAGS='-fno-pie' \
-DENABLE_LTO='TRUE' \
-DENABLE_QT2='TRUE' \
-DUSE_SHARED_ENET='TRUE' \
-DDISTRIBUTOR='aur.archlinux.org'
make
}
package_dolphin-emu-git() {
provides=('dolphin-emu')
conflicts=('dolphin-emu')
cd dolphin-emu/build
make DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}"/usr/bin/dolphin-emu-{nogui,qt2}
install -Dm 644 ../Data/51-usb-device.rules -t "${pkgdir}"/usr/lib/udev/rules.d/
}
package_dolphin-emu-cli-git() {
depends=('dolphin-emu-git')
cd dolphin-emu/build
install -dm 755 "${pkgdir}"/usr/bin
install -m 755 Binaries/dolphin-emu-nogui "${pkgdir}"/usr/bin/dolphin-emu-cli
}
package_dolphin-emu-qt-git() {
depends=('dolphin-emu-git' 'qt5-base')
cd dolphin-emu/build
install -dm 755 "${pkgdir}"/usr/bin
install -m 755 Binaries/dolphin-emu-qt2 "${pkgdir}"/usr/bin/
}
# vim: ts=2 sw=2 et:
|