blob: b54d2563d64abc2a3c15c079c5c482c723f56ae8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
_pkgname=dolphin
pkgname="${_pkgname}-tabopts"
pkgver=22.08.2
pkgrel=1
pkgdesc='KDE File Manager (with tab options patch)'
arch=(x86_64)
url='https://apps.kde.org/dolphin/'
license=(LGPL)
depends=(
'baloo-widgets'
'kactivities'
'kcmutils'
'kio-extras'
'knewstuff'
'kparts'
'kuserfeedback'
)
makedepends=(extra-cmake-modules kdoctools)
optdepends=(
'ffmpegthumbs: video thumbnails'
'kde-cli-tools: for editing file type options'
'kdegraphics-thumbnailers: PDF and PS thumbnails'
'konsole: terminal panel'
'purpose: share context menu'
)
provides=("$_pkgname")
conflicts=("$_pkgname")
groups=(kde-applications kde-system)
source=(
https://download.kde.org/stable/release-service/$pkgver/src/$_pkgname-$pkgver.tar.xz
"tab-options.patch"::"https://invent.kde.org/system/dolphin/-/merge_requests/269.patch"
)
sha256sums=(
'39f2ee237ee5e62baf05e3798d8512e01a7d40276fca03488e256c6e30543b56'
'5fdc620d687ad0d8a6ca6f5e0457b7130b10da2a87a1e10bf1ef41295f8bf3a7'
)
prepare() {
cd "${srcdir}/${_pkgname}-${pkgver}"
patch -p1 -i "${srcdir}/tab-options.patch"
}
build() {
cmake -B build -S "${_pkgname}-${pkgver}" \
-DBUILD_TESTING=OFF
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
}
|