blob: 986a7f9881a4b8c36a129e3b7f6e08b6049a9b94 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Kaizhao Zhang <zhangkaizhao@gmail.com>
_pkgname=dooble
_repourl="https://github.com/textbrowser/dooble"
pkgname=dooble-bin
pkgver=2022.10.15
pkgrel=1
pkgdesc="Dooble is the scientific browser"
arch=('x86_64')
url="https://textbrowser.github.io/dooble/"
license=('BSD')
conflicts=('dooble')
options=('!strip')
depends=('gmime3' 'libxkbcommon-x11' 'nspr' 'nss' 'xcb-util-image' 'xcb-util-keysyms' 'xcb-util-renderutil' 'xcb-util-wm')
source=(
"https://github.com/textbrowser/dooble/releases/download/${pkgver}/Dooble-${pkgver}_amd64.deb"
"LICENSE-${pkgver}::${_repourl}/raw/${pkgver}/LICENSE"
)
noextract=("Dooble-${pkgver}_amd64.deb")
sha256sums=('b627238a1a77a75b7666101861c2deb6620c0350ee37e0ed73b1cc430c176ab3'
'c60bf2d6a8bfdf7c7418bba91c6767cbb4b48dccae36dd5d9ffdb48f756815dd')
package() {
bsdtar -O -xf "Dooble-${pkgver}_amd64.deb" data.tar.zst | bsdtar -C "${pkgdir}" -xf -
# Permission fix
find "${pkgdir}" -type d -exec chmod 755 {} +
# Documentation
install -d "${pkgdir}/usr/share/doc"
ln -s "/opt/dooble/Documentation" "${pkgdir}/usr/share/doc/${_pkgname}"
# License
install -D -m644 "LICENSE-${pkgver}" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}
|