PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Slash <demodevil5 [at] yahoo [dot] com>

pkgname=doom3-cdoom
pkgver=1.3.1
pkgrel=2
pkgdesc='Classic Doom: Doom 1 shareware episode maps recreated for use with Doom 3.'
url='https://www.moddb.com/mods/classic-doom-3'
license=('custom')
arch=('any')
depends=('doom3' 'sh')
# Download: http://www.gamefront.com/files/files/9003559/classic_doom_3_1.3.1.zip
source=('https://www.slashbunny.com/aur/doom3-cdoom/classic_doom_3_131.zip' 'doom3-cdoom.desktop' 'doom3-cdoom.launcher')
sha256sums=('32ed98f373573906d5f5082ad9a09ae0d65e4ae7c47e42cee8468b95e4ce8171'
            'e771efcb2178389cfd73d4ba59c4b78ce226d42f82ccba9859f597291bbecad5'
            '62f81a078d70b5474f9b6829d76835ea58b50dc40ee120649d7b19d6d456714e')
PKGEXT='.pkg.tar'

package() {
    cd ${srcdir}

    # Create Destination Directories
    install -d ${pkgdir}/{usr/bin/,opt/doom3/}

    # Remove Unneeded Files
    rm ${srcdir}/cdoom/{*.url,*.bat}

    # Move Icon
    mv ${srcdir}/cdoom/cdoom.ico ${srcdir}/doom3-cdoom.ico

    # Move License
    mv ${srcdir}/cdoom/docs/License.txt ${srcdir}/License.txt

    # Move Data to Destination Directory
    mv ${srcdir}/cdoom ${pkgdir}/opt/doom3/

    # Install Launcher (Client)
    install -D -m 755 ${srcdir}/doom3-cdoom.launcher \
        ${pkgdir}/usr/bin/doom3-cdoom

    # Install License
    install -D -m 644 ${srcdir}/License.txt \
        ${pkgdir}/usr/share/licenses/$pkgname/License.txt

    # Install Icon
    install -D -m 644 ${srcdir}/doom3-cdoom.ico \
        ${pkgdir}/usr/share/pixmaps/doom3-cdoom.ico

    # Install Desktop File
    install -D -m 644 ${srcdir}/doom3-cdoom.desktop \
        ${pkgdir}/usr/share/applications/doom3-cdoom.desktop
}