blob: 53e793a09955f1767de2ab0cdbcfe74765f5c6fa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: George Rawlinson <george@rawlinson.net.nz>
# Contributor: Michael Straube <straubem@gmx.de>
pkgname=doomretro
pkgver=3.5.1
pkgrel=1
pkgdesc='The classic, refined DOOM source port'
arch=('x86_64')
url='http://doomretro.com'
license=('GPL3')
depends=('sdl2_image' 'sdl2_mixer')
makedepends=('cmake')
optdepends=('timidity++: for music playback')
noextract=("$pkgname-$pkgver.tar.gz")
source=("$pkgname-$pkgver.tar.gz::https://github.com/bradharding/doomretro/archive/v$pkgver.tar.gz")
sha512sums=('c38bd65c84fdf1dec7bb5436807b54578e6793203c592551d99a81657e5cb5618ed80e6807dbb7228d5293ea9823b6caa80b9a9d99e84b7f607d630312d69311')
prepare() {
# 3.2 and later versions can't be extracted by bsdtar
tar xf "$pkgname-$pkgver.tar.gz"
mkdir -p build
}
build() {
cd build
cmake ../$pkgname-$pkgver \
-DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|