summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 38553b0715288f05bf9c513b6686b07f22b2e08c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: Frederic Bezies <fredbezies at gmail dot com>
# Contributor: Kaan Kasım <kaankasim88@gmail.com>

pkgname=doomretro-git
pkgver=3.5.4.r20.gba00a71d
pkgrel=1
pkgdesc='The classic, refined DOOM source port (git version)'
arch=('i686' 'x86_64')
url='http://doomretro.com'
license=('GPL3')
depends=('sdl2_image' 'sdl2_mixer')
makedepends=('cmake' 'git')
optdepends=('timidity++: for music playback')
provides=('doomretro')
conflicts=('doomretro')
source=("git+https://github.com/bradharding/doomretro.git")
sha256sums=('SKIP')

pkgver() {
  cd doomretro
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../doomretro \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}